ECKIT-635 FAM Mock and data structures on FAM via OpenFAM lib

.gitignore

@@ -13,3 +13,4 @@ build/
 tests/geo/eckit_geo_cache
 _build
 *.ccls-cache
+compile_commands.json

CMakeLists.txt

@@ -106,6 +106,26 @@ if( NOT TARGET OpenMP::OpenMP_CXX )
     set( eckit_HAVE_OMP 0 )
 endif()
 
+find_package(LibUUID QUIET)
+find_package(LibOPENFAM QUIET)
+
+### OpenFAM Support
+
+ecbuild_add_option( FEATURE OPENFAM
+                    DEFAULT ON
+                    CONDITION LibUUID_FOUND AND LibOPENFAM_FOUND
+                    DESCRIPTION "Enables OpenFAM support" )
+
+ecbuild_add_option( FEATURE OPENFAM_MOCK
+                    DEFAULT ON
+                    CONDITION LibUUID_FOUND AND NOT LibOPENFAM_FOUND
+                    DESCRIPTION "Enables OpenFAM Mock for testing and development." )
+
+if( eckit_HAVE_OPENFAM_MOCK )
+    add_subdirectory( src/eckit/io/fam/openfam_mock )
+    set( eckit_HAVE_OPENFAM 1 )
+endif()
+
 ### RADOS
 
 ecbuild_add_option( FEATURE RADOS

cmake/FindLibOPENFAM.cmake

@@ -0,0 +1,104 @@
+# Copyright 2024- European Centre for Medium-Range Weather Forecasts (ECMWF)
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     https://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+# In applying this licence, ECMWF does not waive the privileges and immunities
+# granted to it by virtue of its status as an intergovernmental organisation nor
+# does it submit to any jurisdiction.
+#
+# Requires:
+#  FindPackageHandleStandardArgs (CMake standard module)
+#
+
+#[=======================================================================[.rst:
+FindLibOPENFAM
+--------------
+
+This module finds the libopenfam (Fabric-Attached Memory) library.
+
+Imported Targets
+^^^^^^^^^^^^^^^^
+
+This module provides the following imported targets, if found:
+
+``LibOPENFAM``
+  The libopenfam library
+
+Result variables
+^^^^^^^^^^^^^^^^
+
+This module will set the following variables in your project:
+
+``LIB_OPENFAM_FOUND``
+  True if the libopenfam library is found.
+``LIB_OPENFAM_INCLUDE_DIRS``
+  Include directories needed to use libopenfam.
+``LIB_OPENFAM_LIBRARIES``
+  Libraries needed to link to libopenfam.
+
+Cache variables
+^^^^^^^^^^^^^^^
+
+The following cache variables may also be set to help find libopenfam library:
+
+``LIB_OPENFAM_INCLUDE_DIR``
+  where to find the libopenfam headers.
+``LIB_OPENFAM_LIBRARY``
+  where to find the libopenfam library.
+
+Hints
+^^^^^
+
+The environment variables ``OPENFAM_DIR`` and ``OPENFAM_PATH``
+may also be set to help find libopenfam library.
+
+#]=======================================================================]
+
+find_path(LIB_OPENFAM_INCLUDE_DIR fam/fam.h
+    HINTS
+        ${OPENFAM_DIR}
+        ${OPENFAM_PATH}
+        ENV OPENFAM_DIR
+        ENV OPENFAM_PATH
+    PATH_SUFFIXES include ../include
+)
+
+find_library(LIB_OPENFAM_LIBRARY
+    NAMES openfam
+    HINTS
+        ${OPENFAM_DIR}
+        ${OPENFAM_PATH}
+        ENV OPENFAM_DIR
+        ENV OPENFAM_PATH
+    PATH_SUFFIXES lib lib64 build/lib build/lib64
+)
+
+include(FindPackageHandleStandardArgs)
+
+find_package_handle_standard_args(LibOPENFAM REQUIRED_VARS
+                                    LIB_OPENFAM_LIBRARY
+                                    LIB_OPENFAM_INCLUDE_DIR)
+
+if (LibOPENFAM_FOUND)
+    set(LIB_OPENFAM_LIBRARIES ${LIB_OPENFAM_LIBRARY})
+    set(LIB_OPENFAM_INCLUDE_DIRS ${LIB_OPENFAM_INCLUDE_DIR})
+    if(NOT TARGET LibOPENFAM)
+        add_library(LibOPENFAM UNKNOWN IMPORTED)
+        set_target_properties(LibOPENFAM PROPERTIES
+            IMPORTED_LOCATION "${LIB_OPENFAM_LIBRARY}"
+            INTERFACE_INCLUDE_DIRECTORIES "${LIB_OPENFAM_INCLUDE_DIR}"
+            INTERFACE_LINK_LIBRARIES "${LIB_OPENFAM_LIBRARY}")
+    endif()
+endif()
+
+mark_as_advanced(LIB_OPENFAM_INCLUDE_DIR LIB_OPENFAM_LIBRARY)

cmake/FindLibUUID.cmake

@@ -0,0 +1,108 @@
+# Copyright 2024- European Centre for Medium-Range Weather Forecasts (ECMWF)
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     https://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+# In applying this licence, ECMWF does not waive the privileges and immunities
+# granted to it by virtue of its status as an intergovernmental organisation nor
+# does it submit to any jurisdiction.
+#
+# Requires:
+#  FindPackageHandleStandardArgs (CMake standard module)
+#
+
+#[=======================================================================[.rst:
+FindLibUUID
+--------
+
+This module finds the libuuid (from util-linux) library.
+
+Imported Targets
+^^^^^^^^^^^^^^^^
+
+This module provides the following imported targets, if found:
+
+``LibUUID``
+  The libuuid library
+
+Result variables
+^^^^^^^^^^^^^^^^
+
+This module will set the following variables in your project:
+
+``LIB_UUID_FOUND``
+  True if the libuuid library is found.
+``LIB_UUID_INCLUDE_DIRS``
+  Include directories needed to use libuuid.
+``LIB_UUID_LIBRARIES``
+  Libraries needed to link to libuuid.
+
+Cache variables
+^^^^^^^^^^^^^^^
+
+The following cache variables may also be set to help find libuuid library:
+
+``LIB_UUID_INCLUDE_DIR``
+  where to find the libuuid headers.
+``LIB_UUID_LIBRARY``
+  where to find the libuuid library.
+
+Hints
+^^^^^
+
+The environment variables ``LIB_UUID_ROOT``, ``LIB_UUID_DIR``, and ``LIB_UUID_PATH``
+may also be set to help find libuuid library.
+
+#]=======================================================================]
+
+find_path(LIB_UUID_INCLUDE_DIR uuid.h
+    HINTS
+        ${LIB_UUID_ROOT}
+        ${LIB_UUID_DIR}
+        ${LIB_UUID_PATH}
+        ENV LIB_UUID_ROOT
+        ENV LIB_UUID_DIR
+        ENV LIB_UUID_PATH
+    PATH_SUFFIXES uuid
+)
+
+find_library(LIB_UUID_LIBRARY
+    NAMES uuid
+    HINTS
+        ${LIB_UUID_ROOT}
+        ${LIB_UUID_DIR}
+        ${LIB_UUID_PATH}
+        ENV LIB_UUID_ROOT
+        ENV LIB_UUID_DIR
+        ENV LIB_UUID_PATH
+    PATH_SUFFIXES lib lib64
+)
+
+include(FindPackageHandleStandardArgs)
+
+find_package_handle_standard_args(LibUUID REQUIRED_VARS
+                                    LIB_UUID_LIBRARY
+                                    LIB_UUID_INCLUDE_DIR)
+
+if (LibUUID_FOUND)
+    set(LIB_UUID_LIBRARIES ${LIB_UUID_LIBRARY})
+    set(LIB_UUID_INCLUDE_DIRS ${LIB_UUID_INCLUDE_DIR})
+    if(NOT TARGET LibUUID)
+        add_library(LibUUID UNKNOWN IMPORTED)
+        set_target_properties(LibUUID PROPERTIES
+            IMPORTED_LOCATION "${LIB_UUID_LIBRARY}"
+            INTERFACE_INCLUDE_DIRECTORIES "${LIB_UUID_INCLUDE_DIR}"
+            INTERFACE_LINK_LIBRARIES "${LIB_UUID_LIBRARY}")
+    endif()
+endif()
+
+mark_as_advanced(LIB_UUID_INCLUDE_DIR LIB_UUID_LIBRARY)

src/eckit/CMakeLists.txt

@@ -268,6 +268,48 @@ list(APPEND eckit_message_srcs
     message/Splitter.h
 )
 
+# FAM support
+
+list( APPEND eckit_io_srcs
+    io/fam/FamTypes.h
+)
+
+if( eckit_HAVE_OPENFAM )
+    list( APPEND eckit_io_srcs
+        io/fam/FamHandle.cc
+        io/fam/FamHandle.h
+        io/fam/FamList.cc
+        io/fam/FamList.h
+        io/fam/FamListIterator.cc
+        io/fam/FamListIterator.h
+        io/fam/FamMap.cc
+        io/fam/FamMap.h
+        io/fam/FamMapEntry.h
+        io/fam/FamMapIterator.cc
+        io/fam/FamMapIterator.h
+        io/fam/FamName.cc
+        io/fam/FamName.h
+        io/fam/FamObject.cc
+        io/fam/FamObject.h
+        io/fam/FamObjectName.cc
+        io/fam/FamObjectName.h
+        io/fam/FamPath.cc
+        io/fam/FamPath.h
+        io/fam/FamProperty.cc
+        io/fam/FamProperty.h
+        io/fam/FamRegion.cc
+        io/fam/FamRegion.h
+        io/fam/FamRegionName.cc
+        io/fam/FamRegionName.h
+        io/fam/FamSession.cc
+        io/fam/FamSession.h
+        io/fam/FamSessionManager.cc
+        io/fam/FamSessionManager.h
+        io/fam/FamURIManager.cc
+        io/fam/FamURIManager.h
+    )
+endif( eckit_HAVE_OPENFAM )
+
 if(HAVE_RADOS)
     list( APPEND eckit_io_srcs
         io/rados/RadosHandle.cc
@@ -830,6 +872,7 @@ list( APPEND eckit_transaction_srcs
 list( APPEND eckit_testing_srcs
     testing/Filesystem.cc
     testing/Filesystem.h
+    testing/ProcessFork.h
     testing/Test.h
     testing/Filesystem.cc
     testing/Filesystem.h
@@ -928,6 +971,7 @@ ecbuild_add_library(
               "${RADOS_INCLUDE_DIRS}"
               "${OPENSSL_INCLUDE_DIR}"
               "${AIO_INCLUDE_DIRS}"
+              "${LIB_OPENFAM_INCLUDE_DIRS}"
 
           PRIVATE_LIBS
               "${SNAPPY_LIBRARIES}"
@@ -937,6 +981,8 @@ ecbuild_add_library(
               "${CURL_LIBRARIES}"
               "${AIO_LIBRARIES}"
               "${RADOS_LIBRARIES}"
+              $<$<BOOL:${eckit_HAVE_OPENFAM}>:LibUUID>
+              $<$<BOOL:${eckit_HAVE_OPENFAM}>:LibOPENFAM>
               $<${HAVE_AEC}:libaec::aec>
 
           PUBLIC_LIBS

src/eckit/exception/Exceptions.cc

@@ -8,13 +8,14 @@
  * does it submit to any jurisdiction.
  */
 
+#include "eckit/exception/Exceptions.h"
+
 #include <unistd.h>
 
 #include <csignal>
 #include <cstdlib>
 
 #include "eckit/config/LibEcKit.h"
-#include "eckit/exception/Exceptions.h"
 #include "eckit/log/Log.h"
 #include "eckit/os/BackTrace.h"
 #include "eckit/thread/ThreadSingleton.h"
@@ -155,6 +156,15 @@ Cancel::Cancel(const std::string& w, const CodeLocation& loc) : Exception("Cance
 
 Retry::Retry(const std::string& w, const CodeLocation& loc) : Exception("Retry: " + w, loc) {}
 
+PermissionDenied::PermissionDenied(const std::string& w, const CodeLocation& loc) :
+    Exception("Permission denied: " + w, loc) {}
+
+NotFound::NotFound(const std::string& w, const CodeLocation& loc) : Exception("Not found: " + w, loc) {}
+
+AlreadyExists::AlreadyExists(const std::string& w, const CodeLocation& loc) : Exception("Already exists: " + w, loc) {}
+
+OutOfStorage::OutOfStorage(const std::string& w, const CodeLocation& loc) : Exception("Out of storage: " + w, loc) {}
+
 UserError::UserError(const std::string& w, const CodeLocation& loc) : Exception("UserError: " + w, loc) {}
 
 UserError::UserError(const std::string& user, const std::string& w, const CodeLocation& loc) :

src/eckit/exception/Exceptions.h

@@ -187,6 +187,30 @@ class Retry : public Exception {
     explicit Retry(const std::string&, const CodeLocation& = {});
 };
 
+class PermissionDenied : public Exception {
+public:
+
+    explicit PermissionDenied(const std::string& /* w */, const CodeLocation& = {});
+};
+
+class NotFound : public Exception {
+public:
+
+    explicit NotFound(const std::string& /* w */, const CodeLocation& = {});
+};
+
+class AlreadyExists : public Exception {
+public:
+
+    explicit AlreadyExists(const std::string& /* w */, const CodeLocation& = {});
+};
+
+class OutOfStorage : public Exception {
+public:
+
+    explicit OutOfStorage(const std::string& /* w */, const CodeLocation& = {});
+};
+
 class UserError : public Exception {
 public:
 

src/eckit/filesystem/URI.cc

@@ -67,6 +67,9 @@ URI::URI(const std::string& scheme, const URI& uri, const std::string& hostname,
     fragment_(uri.fragment_),
     queryValues_(uri.queryValues_) {}
 
+URI::URI(std::string scheme, const net::Endpoint& endpoint, std::string name) noexcept :
+    name_(std::move(name)), scheme_(std::move(scheme)), host_(endpoint.host()), port_(endpoint.port()) {}
+
 URI::URI(Stream& s) {
     s >> scheme_;
     s >> user_;