ethermint/flake.nix at develop · songgaoye/ethermint · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/release-25.11";
    flake-utils.url = "github:numtide/flake-utils";
    poetry2nix = {
      url = "github:nix-community/poetry2nix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      poetry2nix,
    }:
    let
      rev = self.shortRev or "dirty";
      mkApp = drv: {
        type = "app";
        program = "${drv}/bin/${drv.meta.mainProgram}";
      };
    in
    (flake-utils.lib.eachDefaultSystem (
      system:
      let
        # Import niv sources to maintain single source of truth for dependencies
        sources = import ./nix/sources.nix;

        # Custom gomod2nix overlay that avoids darwin.apple_sdk_11_0 reference
        # Uses the same gomod2nix version as niv to prevent drift between flake and niv builds
        gomodOverlay = final: prev:
          let
            gomodSrc = sources.gomod2nix;
            callPackage = final.callPackage;
            gomodBuilder = callPackage "${gomodSrc}/builder" { };
          in
          {
            inherit (gomodBuilder) buildGoApplication mkGoEnv mkVendorEnv;
            gomod2nix = (callPackage "${gomodSrc}/default.nix" { }).overrideAttrs (_: {
              modRoot = ".";
            });
          };

        pkgs = import nixpkgs {
          inherit system;
          overlays = [
            gomodOverlay
            poetry2nix.overlays.default
          ]
          ++ self.overlays.default;
        };
      in
      rec {
        packages.default = pkgs.callPackage ./. { inherit rev; };
        apps.default = mkApp packages.default;
        devShells = {
          default = pkgs.mkShell {
            buildInputs = [
              packages.default.go
              pkgs.gomod2nix
            ];
          };
          full = pkgs.mkShell {
            buildInputs = [
              packages.default.go
              pkgs.gomod2nix
              pkgs.test-env
            ];
          };
        };
        legacyPackages = pkgs;
      }
    ))
    // {
      overlays.default = [
        (import ./nix/build_overlay.nix)
        (final: super: {
          test-env = final.callPackage ./nix/testenv.nix { };
        })
      ];
    };
}