SensorCast.b4a

Build1=Default,soac.uvigo
File1=Layout.bal
FileGroup1=Default Group
Group=Default Group
Library1=core
Library2=network
Library3=phone
Library4=xui
Library5=json
ManifestCode='This code will be applied to the manifest file during compilation.~\n~'You do not need to modify it in most cases.~\n~'See this link for for more information: https://www.b4x.com/forum/showthread.php?p=78136~\n~AddManifestText(~\n~<uses-sdk android:minSdkVersion="21" android:targetSdkVersion="35"/>~\n~<supports-screens android:largeScreens="true" ~\n~    android:normalScreens="true" ~\n~    android:smallScreens="true" ~\n~    android:anyDensity="true"/>)~\n~SetApplicationAttribute(android:icon, "@drawable/icon")~\n~SetApplicationAttribute(android:label, "$LABEL$")~\n~CreateResourceFromFile(Macro, Themes.LightTheme)~\n~'End of default text.~\n~AddPermission(android.permission.INTERNET)~\n~AddPermission(android.permission.ACCESS_NETWORK_STATE)~\n~AddPermission(android.permission.ACCESS_WIFI_STATE)
Module1=Starter
NumberOfFiles=1
NumberOfLibraries=5
NumberOfModules=1
Version=13.4
@EndOfDesignText@
#Region  Project Attributes 
	#ApplicationLabel: Sensor Android SCOA
	#VersionCode: 1
	#VersionName: 
	'SupportedOrientations possible values: unspecified, landscape or portrait.
	#SupportedOrientations: unspecified
	#CanInstallToExternalStorage: False
#End Region

#Region  Activity Attributes 
	#FullScreen: False
	#IncludeTitle: True
#End Region

Sub Process_Globals
	'These global variables will be declared once when the application starts.
	'These variables can be accessed from all modules.

	Dim U As UDPSocket
	Dim S As ServerSocket
End Sub

Sub Globals
	'These global variables will be redeclared each time the activity is created.
	Dim ps As PhoneSensors
	Dim psa As PhoneSensors
	
	Private LabelMagX As Label
	Private LabelMagY As Label
	Private LabelMagZ As Label
	Private LabelAccX As Label
	Private LabelAccY As Label
	Private LabelAccZ As Label
	Private lblIPServer As Label
	
	Private ListaDeClientes As List
	Dim acc() As Float
	Dim mag() As Float
End Sub

Sub Activity_Create(FirstTime As Boolean)
	Activity.LoadLayout("Layout")
	ps.Initialize(ps.TYPE_MAGNETIC_FIELD)
	psa.Initialize(ps.TYPE_ACCELEROMETER)
	
	
	' Inicializa servidor UDP en el puerto 51042
	U.Initialize("UDP", 51042, 8192)   'tag, puerto, buffer
	
	S.Initialize(0, "S")
	Dim ipAny As String = S.GetMyIP
	Dim ipWifi As String = S.GetMyWifiIP
	Log($"Mi IP: ${ipAny}  (WiFi: ${ipWifi})"$)
	lblIPServer.Text = $"IP: ${ipAny} (WiFi: ${ipWifi})"$
	
	ListaDeClientes.Initialize
End Sub

Sub Activity_Resume
	ps.StartListening("SensorMag")
	psa.StartListening("SensorAcc")
End Sub

Sub Activity_Pause (UserClosed As Boolean)
	ps.StopListening
	psa.StopListening
End Sub

Sub SensorMag_SensorChanged (Values() As Float)
	' Valores del campo magnético en µT
	Dim magX As Float = Values(0)
	Dim magY As Float = Values(1)
	Dim magZ As Float = Values(2)
	mag=Values
	LabelMagX.Text = "X: " & magX
	LabelMagY.Text = "Y: " & magY
	LabelMagZ.Text = "Z: " & magZ
	EnviarDatosUDP
End Sub

Sub SensorAcc_SensorChanged (Values() As Float)
	' Valores del campo magnético en µT
	Dim accX As Float = Values(0)
	Dim accY As Float = Values(1)
	Dim accZ As Float = Values(2)
	acc=Values
	LabelAccX.Text = "X: " & accX
	LabelAccY.Text = "Y: " & accY
	LabelAccZ.Text = "Z: " & accZ
	EnviarDatosUDP
End Sub

Sub EnviarDatosUDP()
	If acc <> Null And mag <> Null And acc.Length > 0 And mag.Length > 0 Then
		Dim Datos As Map
		Datos.Initialize
		' Map para acelerómetro
		Dim accMap As Map
		accMap.Initialize
		accMap.Put("x", acc(0))
		accMap.Put("y", acc(1))
		accMap.Put("z", acc(2))
	    
		' Map para magnetómetro
		Dim magMap As Map
		magMap.Initialize
		magMap.Put("x", mag(0))
		magMap.Put("y", mag(1))
		magMap.Put("z", mag(2))
		Datos.Put("accelerometer", accMap)
		Datos.Put("magnetometer", magMap)
		' Convertir a JSON
		Dim JSONGen As JSONGenerator
		JSONGen.Initialize(Datos)
		Dim jsonString As String = JSONGen.ToString

		' Enviar por UDP a todos los clientes registrados
		For Each Cliente As String In ListaDeClientes
			Dim Packet As UDPPacket
			Packet.Initialize(jsonString.GetBytes("UTF8"), Cliente, 51043) 'puerto de destino
			U.Send(Packet)
		Next
	End If
End Sub

Sub UDP_PacketArrived (Packet As UDPPacket)
	Dim msg As String
	msg = BytesToString(Packet.Data, Packet.Offset, Packet.Length, "UTF8")
    
	Log($"Paquete recibido de: ${Packet.Host} con mensaje: "${msg}"$)

	' 1. Comprobamos si es un mensaje de registro de un nuevo cliente
	If msg = "HOLA" Then
        
		' 2. Verificamos si la IP del cliente NO está ya en la lista
		If ListaDeClientes.IndexOf(Packet.Host) = -1 Then
			' 3. Si es nuevo, lo añadimos a la lista
			ListaDeClientes.Add(Packet.Host)
			LogColor($"Nuevo cliente detectado y añadido: ${Packet.Host}"$, Colors.Green)
			Log($"Clientes conectados: ${ListaDeClientes.Size}"$)
		Else
			LogColor($"El cliente ${Packet.Host} ya estaba registrado."$, Colors.Blue)
		End If
	End If
    
	' Aquí podrías añadir un 'Else If msg = "UNREGISTER_ME"' para que los clientes se den de baja
    
End Sub