SymCrypt/scIntoWindows.cmd at master · TYoungSL/SymCrypt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
set ScTempDir=%TEMP%\SymCryptIntoWindowsTemp

@IF /I "%1" EQU "" (
@echo Usage ScIntoWindows CABfile [noRefCopy]
goto error
)

@if NOT EXIST %1 (
echo Could not find file %1
goto error
)

@if /I "%~x1" NEQ ".CAB" (
echo Not a CAB file: %1
goto error
)

if EXIST %ScTempDir% (
    rd /s /q %ScTempDir%
    @if ERRORLEVEL 1 (
    echo rd failed
    goto error
    )
)

md %ScTempDir%
@if ERRORLEVEL 1 (
echo md failed
goto error
)

copy %1 %ScTempDir%
extract /L %ScTempDir% %1 *.*
@if ERRORLEVEL 1 (
echo Extract failed
goto error
)

pushd %SDXROOT%\minio\published
@if ERRORLEVEL 1 (
echo Pushd failed
goto error
)

for %%a in (amd64chk amd64fre armchk armfre x86chk x86fre arm64chk arm64fre) do (
	copy %ScTempDir%\lib\%%a\symcrypt.lib lib\%%a\SymCrypt.w
	@if ERRORLEVEL 1 (
	echo Copy failed
	goto error
	)
)

copy %ScTempDir%\inc\symcrypt.h inc\ds\symcrypt.w
@if ERRORLEVEL 1 (
echo Copy failed
goto error
)
copy %ScTempDir%\inc\symcrypt_low_level.h inc\ds\symcrypt_low_level.w
@if ERRORLEVEL 1 (
echo Copy failed
goto error
)
copy %ScTempDir%\inc\symcrypt_internal.h inc\ds\symcrypt_internal.w
@if ERRORLEVEL 1 (
echo Copy failed
goto error
)
copy %ScTempDir%\inc\symcrypt_internal_shared.inc inc\ds\symcrypt_internal_shared.inc
@if ERRORLEVEL 1 (
echo Copy failed
goto error
)

popd
pushd %SDXROOT%\onecore\ds\security\cryptoapi\ncrypt\test\unittest
@if ERRORLEVEL 1 (
echo Pushd to DSTEST failed
goto error
)

for %%a in (amd64chk amd64fre armchk armfre x86chk x86fre arm64fre arm64chk) do (
	copy %ScTempDir%\lib\%%a\symcryptunittest.exe %%a\symcryptunittest.exx
	@if ERRORLEVEL 1 (
	echo Copy failed
	goto error
	)
)

popd


@IF /I "%2" NEQ "" (
goto noRefCopy
)

set ScReferenceCopy=\\fsu\shares\SymCrypt\SymCrypt_Windows_Latest
set ScCabCopy=\\fsu\shares\SymCrypt\SymCryptCabs

copy %1 %ScCabCopy%

rd /s /q %ScReferenceCopy%

robocopy %scTempDir% %ScReferenceCopy% /s
@if ERRORLEVEL 2 (
echo RoboCopy failed
goto error
)
attrib +r %ScReferenceCopy%\*.* /s
@if ERRORLEVEL 1 (
echo Attrib failed to make reference copy read-only
goto error
)

:noRefCopy

@echo ---------------- Success! ---------------------
@goto done

:error
@echo **************** ERROR! ***********************

:done
@set ScTempDir=
@set ScReferenceCopy=
@set ScCabCopy=