TUD/flake.nix at main · Sobottasgithub/TUD · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
{
  description = "Tablo Udp Discovery";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";

    tablog = {
      url = "github:Sobottasgithub/tablog";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      tablog,
    }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs { inherit system; };

      version = "1.0.0";

      libtablog = tablog.packages.${system}.lib;

      commonDeps = with pkgs; [
        cmake
        gcc
        gnumake
        libtasn1
        libtablog
      ];

      mkTUDPackage =
        {
          pname,
          buildTarget,
          enableLib ? false,
          enableClient ? false,
          enableServer ? false,
          enablePeer ? false,
          extraInputs ? [ ],
        }:
        pkgs.stdenv.mkDerivation {
          inherit pname version;
          src = ./.;

          buildInputs = commonDeps ++ extraInputs;

          configurePhase = ''
            cmake -B build -S $src \
              -DCMAKE_BUILD_TYPE=Release \
              -DDEF_TUD=${if enableLib then "ON" else "OFF"} \
              -DDEF_CLIENT=${if enableClient then "ON" else "OFF"} \
              -DDEF_SERVER=${if enableServer then "ON" else "OFF"} \
              -DDEF_PEER=${if enablePeer then "ON" else "OFF"}
          '';

          buildPhase = ''
            cmake --build build \
              --target ${buildTarget} \
              -j$NIX_BUILD_CORES
          '';

          installPhase = ''
            cmake --install build --prefix=$out
            cp LICENSE $out/
          '';
        };

    in
    {
      packages.${system} =
        let
          lib = mkTUDPackage {
            pname = "libtud";
            buildTarget = "tud";
            enableLib = true;
          };
        in
        {
          inherit lib libtablog;

          client = mkTUDPackage {
            pname = "tud-client";
            buildTarget = "tud-client";
            enableClient = true;
            extraInputs = [ lib ];
          };

          server = mkTUDPackage {
            pname = "tud-server";
            buildTarget = "tud-server";
            enableServer = true;
            extraInputs = [ lib ];
          };

          peer = mkTUDPackage {
            pname = "tud-peer";
            buildTarget = "tud-peer";
            enablePeer = true;
            extraInputs = [ lib ];
          };

          full = mkTUDPackage {
            pname = "libtud-full";
            buildTarget = "all";
            enableLib = true;
            enableServer = true;
            enableClient = true;
            enablePeer = false;
          };

          default = self.packages.${system}.lib;
        };

      devShells.${system}.default = pkgs.mkShell {
        packages = commonDeps ++ [
          pkgs.bridge-utils
          pkgs.clang-tools
        ];

        shellHook = ''
          git status
        '';
      };
    };
}