i3status/flake.nix at master · SimulaVR/i3status · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/63dacb46bf939521bdc93981b4cbb7ecb58427a0";
    systems.url = "github:nix-systems/x86_64-linux";
    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      systems = import inputs.systems;

      imports = [ inputs.treefmt-nix.flakeModule ];

      perSystem =
        { pkgs, lib, ... }:
        let
          i3status = pkgs.stdenv.mkDerivation rec {
            pname = "i3status";
            version = "2.13";
            src = lib.cleanSource ./.;

            nativeBuildInputs = [
              pkgs.pkg-config
              pkgs.asciidoc
              pkgs.xmlto
              pkgs.docbook_xml_dtd_45
              pkgs.docbook_xsl
            ];

            buildInputs = [
              pkgs.libconfuse
              pkgs.yajl
              pkgs.libpulseaudio
              pkgs.libnl
              pkgs.alsa-lib
            ];

            makeFlags = [
              "all"
              "PREFIX=$(out)"
            ];

            # This hack is needed because for unknown reasons configure generates a broken makefile on the 2.13 release under nixos
            preBuild = ''
              sed -i -e 's/\$(TEST_LOGS) \$(TEST_LOGS/\$(TEST_LOGS)/g' Makefile
            '';

            meta = {
              description = "Generates a status line for i3bar, dzen2, xmobar or lemonbar";
              homepage = "https://i3wm.org";
              license = lib.licenses.bsd3;
              platforms = [ "x86_64-linux" ];
            };
          };
        in
        {
          treefmt = {
            projectRootFile = "flake.nix";
            programs.nixfmt.enable = true;
          };

          packages = {
            inherit i3status;
            default = i3status;
          };

          devShells.default = pkgs.mkShell rec {
            nativeBuildInputs = [
              # Development tools
              pkgs.nil
            ];

            shellHook = ''
              export PS1="\n[nix-shell:\w]$ "
            '';
          };
        };
    };
}