justfile

set windows-shell := ["powershell.exe", "-c"]
set dotenv-filename := ".env"

container-name := "db_postgres"
db-user := "postgres"
db-port := "postgres"


export PYTHONPATH := "src"

run:
    uv run python src/main.py

run-docker:
    docker-compose up --build

test path="tests":
    uv run pytest {{ path }}

coverage:
    uv run pytest tests --cov=src --cov-report=term-missing --cov-report=html

pre-commit-all:
    pre-commit run --all-files --show-diff-on-failure

alembic-gen:
    alembic revision --autogenerate

alembic-upg revision="head":
    alembic upgrade {{ revision }}

alembic-drop revision="base":
    alembic downgrade {{ revision }}

create-db db-name="some_db":
    docker exec -it {{ container-name }} psql -U {{ db-user }} -c "CREATE DATABASE {{ db-name }};"

# Drop database (force disconnect and drop)
delete-db db-name="some_db":
    docker exec -it {{ container-name }} psql -U {{ db-user }} -c "SELECT pg_terminate_backend(pg_stat_activity.pid) FROM pg_stat_activity WHERE pg_stat_activity.datname = '{{ db-name }}' AND pid <> pg_backend_pid();"
    docker exec -it {{ container-name }} psql -U {{ db-user }} -c "DROP DATABASE IF EXISTS {{ db-name }};"

# Recreate database (drop and create)
recreate-db db-name="some_db":
    just delete-db {{ db-name }}
    just create-db {{ db-name }}
    just alembic-upg

upg:
    uv sync --upgrade

ruff-c:
    ruff check ./src --fix --config ./pyproject.toml

ruff-f:
    ruff format ./src --config ./pyproject.toml

mypy:
    mypy ./src --config-file ./pyproject.toml

lint: ruff-c ruff-f mypy