build.gradle

plugins {
    id 'java'
    id 'checkstyle'
    id 'maven-publish'
    id 'com.gradleup.shadow' version '9.3.1'
    id 'io.sentry.jvm.gradle' version '6.1.0'
}

group = 'com.hyperfactions'
version = '0.14.0'

// Shared version property avoids accessing project at execution time
def buildVersion = objects.property(String).convention(version)

// Override version for dev builds
gradle.taskGraph.whenReady { graph ->
    if (graph.hasTask(':buildDev')) {
        project.version = '0.0.0'
        buildVersion.set('0.0.0')
    }
}

// Resolve Hytale server version (standalone fallback for JitPack / CI builds)
def hytaleChannel = (findProperty('hytale_channel') ?: 'release').toString().trim()
def hytaleServerVersion = {
    // Prefer root project version (monorepo), fall back to self-resolution
    if (rootProject.hasProperty('hytaleVersion')) return rootProject.hytaleVersion
    def override = (findProperty('hytale_server_version') ?: '').toString().trim()
    if (override) return override
    try {
        def url = "https://maven.hytale.com/${hytaleChannel}/com/hypixel/hytale/Server/maven-metadata.xml"
        def text = new URI(url).toURL().text
        def m = text =~ /<release>(.+?)<\/release>/
        if (m.find()) return m.group(1)
    } catch (ignored) {}
    throw new GradleException("Could not resolve Hytale server version")
}()

// Detect monorepo vs standalone (JitPack / CI) build context
def isMonorepo = rootProject.name == 'HyperSystems'

// Check if optional local dependencies are available (WiFlowExpansion needs WiFlow API to compile)
def hasWiFlowLib = file('libs').listFiles()?.any { it.name.contains('WiFlow') } ?: false

// HyperPerms may be provided as a local jar in libs/ (dev) instead of resolved from JitPack (CI)
def hasHyperPermsLib = file('libs').listFiles()?.any { it.name.contains('HyperPerms') } ?: false

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(25)
    }
}

repositories {
    mavenCentral()
    maven { url = "https://maven.hytale.com/${hytaleChannel}" }
    maven { url = 'https://repo.helpch.at/releases/' }
    if (!isMonorepo) {
        // Standalone build: resolve HyperPerms from JitPack
        maven { url = 'https://jitpack.io' }
    }
}

dependencies {
    // Hytale Server API
    compileOnly "com.hypixel.hytale:Server:${hytaleServerVersion}"

    // HyperPerms soft dependency (for compile-time reference only).
    // Local dev provides libs/HyperPerms.jar (picked up by the libs fileTree below);
    // CI/JitPack builds without it resolve from the published tag.
    if (isMonorepo) {
        compileOnly project(':HyperPerms')
    } else if (!hasHyperPermsLib) {
        compileOnly 'com.github.HyperSystems-Development:HyperPerms:v2.9.6'
    }

    // JSON handling
    implementation 'com.google.code.gson:gson:2.11.0'

    // Sentry error tracking (bundled in shadow JAR)
    implementation 'io.sentry:sentry:8.33.0'

    // PlaceholderAPI Hytale (soft dependency - compileOnly)
    compileOnly 'at.helpch:placeholderapi-hytale:1.0.4'

    // Optional local soft dependencies (only available in monorepo dev environment)
    // WiFlowPlaceholderAPI and GravestonePlugin integrations use reflection so the build
    // succeeds without them. WiFlowExpansion.java is conditionally excluded below.
    // Exclude any local Hytale Server jar: the server API must come exclusively from the
    // channel-resolved maven dependency (-Phytale_channel), otherwise a stale HytaleServer.jar
    // dropped in libs/ would silently shadow it and defeat the release/pre-release switch.
    compileOnly fileTree('libs') { include '*.jar'; exclude 'HytaleServer*.jar', 'Server-*.jar' }

    // Null safety annotations
    compileOnly 'org.jetbrains:annotations:24.1.0'
    testCompileOnly 'org.jetbrains:annotations:24.1.0'

    // Testing
    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.2'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

// WiFlowExpansion extends PlaceholderExpansion (from WiFlowPlaceholderAPI) directly.
// When WiFlow isn't on the classpath (JitPack / CI), exclude it from compilation.
// The bridge class (WiFlowPlaceholderIntegration) loads it reflectively at runtime.
if (!hasWiFlowLib) {
    sourceSets.main.java.exclude '**/WiFlowExpansion.java'
}

// Generate BuildInfo.java with project version
def generatedSrcDir = layout.buildDirectory.dir("generated/sources/buildinfo/java")
sourceSets.main.java.srcDir(generatedSrcDir)

tasks.register('generateBuildInfo') {
    def outputDir = generatedSrcDir
    def ver = buildVersion
    inputs.property('version', ver)
    outputs.dir(outputDir)
    doLast {
        def v = ver.get()
        def dir = outputDir.get().asFile.toPath().resolve("com/hyperfactions").toFile()
        dir.mkdirs()
        new File(dir, "BuildInfo.java").text = """\
package com.hyperfactions;

/**
 * Auto-generated build information.
 */
public final class BuildInfo {
    public static final String VERSION = "${v}";
    public static final String JAVA_VERSION = "${System.getProperty('java.version')}";
    public static final long BUILD_TIMESTAMP = ${System.currentTimeMillis()}L;
    private BuildInfo() {}
}
"""
    }
}

// Generate help .lang files from markdown sources
tasks.register('generateHelpLang', JavaExec) {
    group = 'build'
    description = 'Generate help .lang files from markdown sources'
    dependsOn 'compileJava'
    classpath = sourceSets.main.compileClasspath + files(sourceSets.main.java.classesDirectory)
    mainClass = 'com.hyperfactions.build.HelpLangGenerator'
    args = [
        file('src/main/resources/Server/Languages').absolutePath,
        layout.buildDirectory.dir('generated/resources').get().asFile.absolutePath
    ]
    inputs.dir(file('src/main/resources/Server/Languages'))
    outputs.dir(layout.buildDirectory.dir('generated/resources'))
}

sourceSets.main.resources.srcDir(layout.buildDirectory.dir('generated/resources'))

// Check translations: compare keys in en-US against other locales
tasks.register('checkTranslations') {
    group = 'verification'
    description = 'Report missing translation keys compared to en-US'
    doLast {
        def langDir = file('src/main/resources/Server/Languages')
        def enDir = new File(langDir, 'en-US')
        if (!enDir.exists()) {
            println "No en-US directory found at ${enDir.absolutePath}"
            return
        }
        // Collect en-US keys per file
        def enKeys = [:]
        enDir.listFiles({ f -> f.name.endsWith('.lang') } as FileFilter).each { f ->
            def keys = []
            f.eachLine { line ->
                line = line.trim()
                if (line && !line.startsWith('#') && line.contains('=')) {
                    keys << line.substring(0, line.indexOf('=')).trim()
                }
            }
            enKeys[f.name] = keys
        }
        // Check each locale
        def locales = langDir.listFiles({ f -> f.isDirectory() && f.name != 'en-US' } as FileFilter)
        if (!locales) {
            println "No non-English locales found."
            return
        }
        def totalMissing = 0
        locales.sort { it.name }.each { localeDir ->
            def localeMissing = 0
            enKeys.each { fileName, keys ->
                def localeFile = new File(localeDir, fileName)
                if (!localeFile.exists()) {
                    println "[${localeDir.name}] MISSING FILE: ${fileName} (${keys.size()} keys)"
                    localeMissing += keys.size()
                    return
                }
                def localeKeys = []
                localeFile.eachLine { line ->
                    line = line.trim()
                    if (line && !line.startsWith('#') && line.contains('=')) {
                        localeKeys << line.substring(0, line.indexOf('=')).trim()
                    }
                }
                def missing = keys.findAll { !localeKeys.contains(it) }
                if (missing) {
                    println "[${localeDir.name}] ${fileName}: ${missing.size()} missing keys"
                    missing.each { println "  - ${it}" }
                    localeMissing += missing.size()
                }
            }
            if (localeMissing == 0) {
                println "[${localeDir.name}] All keys present"
            }
            totalMissing += localeMissing
        }
        println "\nTotal missing keys across all locales: ${totalMissing}"
    }
}

// Expand version placeholder in manifest.json
processResources {
    def ver = buildVersion
    def srvVer = hytaleServerVersion
    inputs.property('version', ver)
    inputs.property('serverVersion', srvVer)
    filesMatching('manifest.json') {
        expand(version: ver.get(), serverVersion: srvVer)
    }
}

jar {
    archiveClassifier = 'plain'
}

shadowJar {
    archiveClassifier.set('')

    // Relocate dependencies to avoid conflicts
    relocate 'com.google.gson', 'com.hyperfactions.lib.gson'
    relocate 'io.sentry', 'com.hyperfactions.lib.sentry'

    // Don't minimize - it removes Gson's inner classes needed at runtime
}

test {
    useJUnitPlatform()
}

checkstyle {
    toolVersion = '10.26.1'
    configFile = file('config/checkstyle/checkstyle.xml')
    ignoreFailures = true
    showViolations = true
}

tasks.withType(Checkstyle).configureEach {
    reports {
        xml.required = true
        html.required = true
    }
}

build {
    dependsOn shadowJar
    finalizedBy tasks.matching { it.name == 'sentryUploadSourceBundleJava' }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.compilerArgs.addAll(['-Xlint:all', '-Xlint:-processing'])
}

javadoc {
    options.encoding = 'UTF-8'
    options.charSet = 'UTF-8'
    options.memberLevel = JavadocMemberLevel.PUBLIC
    options.addStringOption('Xdoclint:none', '-quiet')
    options.links(
        'https://docs.oracle.com/en/java/javase/21/docs/api/'
    )
    failOnError = false
}

// Ensure help lang files are generated before processResources copies them
tasks.named('processResources') {
    dependsOn 'generateHelpLang'
}

// Ensure build info is generated and HyperPerms shadowJar is built before compiling
tasks.named('compileJava') {
    dependsOn 'generateBuildInfo'
    if (isMonorepo) {
        dependsOn ':HyperPerms:shadowJar'
    }
}

// Sentry tasks use the same generated sources dir as generateBuildInfo — declare dependencies
tasks.matching { it.name.startsWith('sentry') || it.name.startsWith('generateSentry') }.configureEach {
    dependsOn 'generateBuildInfo'
}

// Dev build task - clean build with version set to 'dev'
tasks.register('buildDev') {
    group = 'build'
    description = 'Clean build with dev version identifier'
    dependsOn 'clean', 'build'
}

tasks.named('build') {
    mustRunAfter 'clean'
}

// Sentry source context upload (reads token from .sentry-auth-token file or SENTRY_AUTH_TOKEN env var)
sentry {
    includeSourceContext = true
    org = "hypersystems"
    projectName = "hyperfactions"
    authToken = {
        def tokenFile = file('.sentry-auth-token')
        if (tokenFile.exists()) return tokenFile.text.trim()
        return System.getenv("SENTRY_AUTH_TOKEN")
    }()
}

// Maven publication for JitPack (publishes API classes, not the shadow JAR)
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            groupId = 'com.hyperfactions'
            artifactId = 'HyperFactions'

            // Strip all dependencies from the POM — consumers provide their own
            pom.withXml {
                def deps = asNode().dependencies
                if (deps) deps.each { asNode().remove(it) }
            }
        }
    }
}