SCsub

#!/usr/bin/env python

from SCons.Script.SConscript import SConsEnvironment
import os
from typing import TYPE_CHECKING

from build import gdre_icon_builder  # pyright: ignore[reportImplicitRelativeImport]
from build.common import add_source_groups, append_cpppaths  # pyright: ignore[reportImplicitRelativeImport]
from build.mono_decomp import (  # pyright: ignore[reportImplicitRelativeImport]
    build_godot_mono_decomp,
    get_godot_mono_decomp_lib_dir,
)
from build.paths import *  # pyright: ignore[reportImplicitRelativeImport]
from build.versioning import write_version_header  # pyright: ignore[reportImplicitRelativeImport]
from build.vtracer import build_vtracer, get_vtracer_lib_dir  # pyright: ignore[reportImplicitRelativeImport]

if TYPE_CHECKING:
    from ...misc.utility.scons_hints import *


Import("env")
Import("env_modules")

MODULE_DIR = get_module_dir(env)
BUILD_DIR = get_build_dir(env)

INCLUDE_DIRS = [
    VTRACER_INCLUDE_DIR,
    GODOT_MONO_DECOMP_INCLUDE_DIR,
    MODULE_INCLUDE_DIR,
    MMP3_THIRDPARTY_DIR,
    LIBOGG_THIRDPARTY_DIR,
    LIBVORBIS_THIRDPARTY_DIR,
    LIBTHEORA_THIRDPARTY_DIR,
    MBEDTLS_THIRDPARTY_DIR,
    UNSIGNED_HASH_INCLUDE_DIR,
    AXML_DEC_INCLUDE_DIR,
]


env_gdsdecomp = env_modules.Clone()

# spirv-interop
spirv_interop_obj = []

spirv_interop_sources: list[str] = []

# if metal isn't being built, we have to build spirv-cross ourselves because it's not being built by the engine
if not "metal" in env or not env["metal"]:
    thirdparty_spirv_headers_dir = "#thirdparty/spirv-headers/"
    thirdparty_dir = "#thirdparty/spirv-cross/"
    spirv_interop_sources = [
        "spirv_cfg.cpp",
        "spirv_cross.cpp",
        "spirv_parser.cpp",
        "spirv_msl.cpp",
        "spirv_reflect.cpp",
        "spirv_glsl.cpp",
        "spirv_cross_parsed_ir.cpp",
        "spirv_cross_util.cpp",
    ]
    spirv_interop_sources = [thirdparty_dir + file for file in spirv_interop_sources]
spirv_interop_sources.append(SPIRV_INTEROP_DIR + "spirv-transpiler.cpp")

env_spirv_interop = env_gdsdecomp.Clone()
env_spirv_interop.disable_warnings()
env_spirv_interop.add_source_files(spirv_interop_obj, spirv_interop_sources)
if env.msvc:
    if "_HAS_EXCEPTIONS" in env_spirv_interop["CPPDEFINES"]:
        env_spirv_interop["CPPDEFINES"].remove("_HAS_EXCEPTIONS")
    env_spirv_interop.Append(CXXFLAGS=["/EHsc"])
else:
    if "-fno-exceptions" in env_spirv_interop["CXXFLAGS"]:
        env_spirv_interop["CXXFLAGS"].remove("-fno-exceptions")
    env_spirv_interop.Append(CXXFLAGS=["-fexceptions"])
append_cpppaths(
    env_spirv_interop,
    [
        SPIRV_INTEROP_DIR,
        SPIRV_CROSS_THIRDPARTY_DIR,
        SPIRV_CROSS_THIRDPARTY_INCLUDE_DIR,
        SPIRV_HEADERS_THIRDPARTY_DIR,
    ],
)
env.modules_sources += spirv_interop_obj  # pyright: ignore[reportAttributeAccessIssue]


if env["tests"]:
    env_gdsdecomp.Append(CPPDEFINES=["TESTS_ENABLED"])

append_cpppaths(
    env_gdsdecomp,
    INCLUDE_DIRS,
)


if env["disable_exceptions"]:
    env_gdsdecomp.Append(CPPDEFINES=["DOCTEST_CONFIG_NO_EXCEPTIONS_BUT_WITH_ALL_ASSERTS"])
env_gdsdecomp.Append(CPPDEFINES=["ENABLE_3_X_SCENE_LOADING"])

env_gdsdecomp["BUILDERS"]["MakeGDREIconsBuilder"] = Builder(
    action=env_gdsdecomp.Run(gdre_icon_builder.make_gdre_icons_action),
    suffix=".h",
    src_suffix=".svg",
)
icon_sources = Glob("icons/*.svg")
env_gdsdecomp.Alias("gdre_icons", [env_gdsdecomp.MakeGDREIconsBuilder("gui/gdre_icons.gen.h", icon_sources)])

write_version_header(os.path.join(MODULE_DIR, "utility", "gdre_version.gen.h"))

if env["builtin_libogg"]:
    env_gdsdecomp.Prepend(CPPPATH=[LIBOGG_THIRDPARTY_DIR])
if env["builtin_libvorbis"]:
    env_gdsdecomp.Prepend(CPPPATH=["#thirdparty/libvorbis"])
env_gdsdecomp.Prepend(CPPPATH=[MMP3_THIRDPARTY_DIR])
if env["builtin_libwebp"]:
    env_gdsdecomp.Prepend(CPPPATH=[WEBP_THIRDPARTY_DIR, WEBP_THIRDPARTY_DIR + "src/"])

env.Append(LIBPATH=[BUILD_DIR])

module_obj = []
common_sources = [
    "*.cpp",
    "bytecode/*.cpp",
    "compat/*.cpp",
    "crypto/*.cpp",
    "exporters/*.cpp",
    "gui/*.cpp",
    "main/*.cpp",
    "plugin_manager/*.cpp",
    "utility/*.cpp",
    "external/axmldec/lib/jitana/util/*.cpp",
    "external/tga/*.cpp",
    "external/tinygltf/tiny_gltf.cc",
    "module_etc_decompress/*.cpp",
    f"{UNSIGNED_HASH_SRC_DIR}/*.cpp",
    f"{UNSIGNED_HASH_SRC_DIR}/*.c",
]
add_source_groups(env_gdsdecomp, module_obj, common_sources)
if env["target"] == "editor":
    add_source_groups(env_gdsdecomp, module_obj, ["editor/*.cpp"])


build_vtracer(root_env=env, env_gdsdecomp=env_gdsdecomp, module_obj=module_obj)

if "disable_gifski" in env and env["disable_gifski"]:
    env_gdsdecomp.Append(CPPDEFINES=["GIFSKI_DISABLED"])
if "disable_godot_mono_decomp" in env and env["disable_godot_mono_decomp"]:
    env_gdsdecomp.Append(CPPDEFINES=["GODOT_MONO_DECOMP_DISABLED"])
else:
    build_godot_mono_decomp(env=env, env_gdsdecomp=env_gdsdecomp, module_obj=module_obj)


if env["tests"]:
    import glob
    import sys

    test_obj = []
    env_tests = env_gdsdecomp.Clone()
    force_link_sources = glob.glob(os.path.join(MODULE_DIR, "tests", "*.cpp"))

    add_source_groups(env_tests, test_obj, ["#modules/gdsdecomp/tests/*.cpp"])
    env.modules_sources += test_obj  # pyright: ignore[reportAttributeAccessIssue]

    test_builders_module_dir = env.Dir("#tests").abspath
    sys.path.insert(0, test_builders_module_dir)
    from test_builders import force_link_builder  # pyright: ignore[reportMissingImports]

    def gen_tests_header_fixed(target, source, env):
        force_link_builder(target, source, env)
        contents = open(str(target[0].abspath), "r", encoding="utf-8").read()
        with open(str(target[0].abspath), "w", encoding="utf-8") as file:
            file.write(contents.replace("force_link_tests()", "force_link_gdre_tests()"))
    sys.path.remove(test_builders_module_dir)

    force_link_header = env.CommandNoCache(
        "#modules/gdsdecomp/tests/gdre_tests_force_link.gen.h",
        env.Value(force_link_sources),
        env.Run(gen_tests_header_fixed),
    )

    env.Depends("#modules/modules_tests.gen.h", force_link_header)


env.modules_sources += module_obj  # pyright: ignore[reportAttributeAccessIssue]