Installer.iss

; Script generated by the Inno Script Studio Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "EDDI"
#define MyAppVersion "4.1.9"
#define MyAppPublisher "Elite Dangerous Community Developers (EDCD)"
#define MyAppURL "https://github.com/EDCD/EDDI/"
#define MyAppExeName "EDDI.exe"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AllowUNCPath=no
AppId={{830C0324-30D8-423C-B5B4-D7EE8D007A79}
AppName={#MyAppName}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
AppVerName={#MyAppName} {#MyAppVersion}
AppVersion={#MyAppVersion}
DefaultDirName={reg:HKCU\Software\VoiceAttack.com\VoiceAttack\LastRun,AppsFolder|{autopf64}\VoiceAttack\Apps}\{#MyAppName}
DefaultGroupName={#MyAppName}
DisableDirPage=no
DisableWelcomePage=no
LicenseFile="{#SourcePath}\LicenseFile.txt"
OutputBaseFilename={#MyAppName}-{#MyAppVersion}
OutputDir="{#SourcePath}\bin\Installer"
SolidCompression=yes
SourceDir="{#SourcePath}\bin\Release"
UninstallDisplayIcon={app}\{#MyAppExeName}
UsePreviousTasks=no
WizardImageFile={#SourcePath}\graphics\logo.bmp
WizardSmallImageFile={#SourcePath}\graphics\logo.bmp

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked
Name: "quicklaunchicon"; Description: "{cm:CreateQuickLaunchIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked; OnlyBelowVersion: 0,6.1

[Files]
Source: "*.exe"; DestDir: "{app}"
Source: "*.exe.config"; DestDir: "{app}"

Source: "x86\*.*"; DestDir: "{app}\x86"; Flags: recursesubdirs createallsubdirs
Source: "x64\*.*"; DestDir: "{app}\x64"; Flags: recursesubdirs createallsubdirs

Source: "*.dll"; DestDir: "{app}"; Excludes: "Tests.dll"
Source: "*.dll.config"; DestDir: "{app}"

Source: "*.resources.dll"; DestDir: "{app}"; Flags: recursesubdirs createallsubdirs
Source: "eddi.json"; DestDir: "{app}"
Source: "eddi.*.json"; DestDir: "{app}"
Source: "*.md"; DestDir: "{app}"
Source: "*.vap"; DestDir: "{app}"

; Remove outdated files
[InstallDelete]
; --- Remove old architecture folders entirely ---
Type: filesandordirs; Name: "{app}\x86"
Type: filesandordirs; Name: "{app}\x64"

; --- Remove all old DLLs in the root folder ---
Type: files; Name: "{app}\*.dll"

; --- Remove old PDBs ---
Type: files; Name: "{app}\*.pdb"

; --- Remove old doc files ---
Type: files; Name: "{app}\*.md"
Type: files; Name: "{app}\*.xml"

; --- Remove old default personality files ---
Type: files; Name: "{app}\eddi.json"
Type: files; Name: "{app}\eddi.*.json"

; --- Remove old VoiceAttack profiles ---
Type: files; Name: "{app}\*.vap"

; --- Remove old resource files that may no longer be valid ---
Type: filesandordirs; Name: "{app}\*\*.resources.dll"

; --- Remove old config files that may no longer be valid ---
Type: files; Name: "{app}\*.dll.config"

; --- Remove old user-specific cached configs that cause runtime mismatches ---
Type: filesandordirs; Name: "{localappdata}\Eddi\Eddi.exe_*"
Type: files; Name: "{localappdata}\Eddi\Eddi.exe_*\*\user.config"

; --- Remove obsolete legacy files from older EDDI versions ---
Type: files; Name: "{app}\*.exe"
Type: files; Name: "{app}\*.exe.config"
Type: files; Name: "{app}\EDDI.ico"
Type: files; Name: "{userappdata}\EDDI\credentials.json"
Type: files; Name: "{userappdata}\EDDI\elite.json"
Type: filesandordirs; Name: "{userappdata}\EDDI\galnet"

; Remove sensitive data on uninstall
[UninstallDelete]
Type: files; Name: "{userappdata}\EDDI\CompanionAPI.json"

[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: quicklaunchicon

[Run]
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent

[ThirdParty]
UseRelativePaths=True

[Messages]
SelectDirBrowseLabel=To continue, click Next. If this is not your VoiceAttack installation location, or you would like to put the EDDI files in a different location, click Browse.

[Registry]
Root: "HKLM"; Subkey: "Software\Classes\eddi"; ValueType: string; ValueData: "EDDI URL Protocol"; Flags: uninsdeletekey
Root: "HKLM"; Subkey: "Software\Classes\eddi"; ValueType: string; ValueName: "URL Protocol"; Flags: uninsdeletekey
Root: "HKLM"; Subkey: "Software\Classes\eddi\Default Icon"; ValueType: string; ValueData: "{app}\{#MyAppExeName},0"; Flags: uninsdeletekey
Root: "HKLM"; Subkey: "Software\Classes\eddi\shell\open\command"; ValueType: string; ValueData: """{app}\{#MyAppExeName}"" ""%1"""; Flags: uninsdeletekey
Root: "HKLM"; Subkey: "Software\Classes\eddi\shell\open\ddeexec"; ValueType: string; ValueData: "%1"; Flags: uninsdeletekey
Root: "HKCU"; Subkey: "Software\Classes\eddi"; ValueType: string; ValueData: "EDDI URL Protocol"; Flags: uninsdeletekey
Root: "HKCU"; Subkey: "Software\Classes\eddi"; ValueType: string; ValueName: "URL Protocol"; Flags: uninsdeletekey
Root: "HKCU"; Subkey: "Software\Classes\eddi\Default Icon"; ValueType: string; ValueData: "{app}\{#MyAppExeName},0"; Flags: uninsdeletekey
Root: "HKCU"; Subkey: "Software\Classes\eddi\shell\open\command"; ValueType: string; ValueData: """{app}\{#MyAppExeName}"" ""%1"""; Flags: uninsdeletekey
Root: "HKCU"; Subkey: "Software\Classes\eddi\shell\open\ddeexec"; ValueType: string; ValueData: "%1"; Flags: uninsdeletekey