Example.hx

package;

import tracker.Entity;
import tracker.Model;
import tracker.ds.ObservableArray;

class Example
{
	static function main()
	{
		new Context();
	}
}

class Context extends Entity
{
	public function new()
	{
		super();

		var testPerson = new Person("Dave", 25);
		testPerson.onNameChange(this, (current, previous) -> {
			trace("Name changed from " + previous + " to " + current);
		});
		testPerson.onAgeChange(this, (current, previous) -> {
			trace("Age changed from " + previous + " to " + current);
		});

		testPerson.name = "John";
		testPerson.age = 30;

		testPerson.nicknames.onChange(this, () -> {
			trace("Nicknames changed!");
		});
		testPerson.nicknames.onItemInserted(this, (index, item) -> {
			trace("Nickname added at " + index + ": " + item);
		});
		testPerson.nicknames.onItemRemoved(this, (index, item) -> {
			trace("Nickname removed at " + index + ": " + item);
		});

		testPerson.nicknames.push("Johnny");
		testPerson.nicknames.push("JP");
		testPerson.nicknames.push("Davy");
		testPerson.nicknames.remove("JP");

		trace('nicknames.length = ${testPerson.nicknames.length}'); // 2
		trace('nicknames[1] = ${testPerson.nicknames[1]}'); // Davy
	}
}


class Person extends Model
{
	@observe public var name:String;
	@observe public var age:Int;
	
	@observe public var nicknames:ObservableArray<String>;

	public function new(name:String, age:Int)
	{
		super();

		this.name = name;
		this.age = age;
		this.nicknames = new ObservableArray();

		autorun(() -> trace('Person: ${this.name}, Age: ${this.age}, Nicknames: ${this.nicknames.toArray()}'));
	}
}