shell/shell.qml at master · At1ass/shell · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
import QtQuick
import Quickshell
import Quickshell.Wayland
import qs.src.features.background
import qs.src.features.dashboard
import qs.src.features.launcher
import qs.src.features.osd
import qs.src.features.notifications
import qs.src.features.statusbar as Bar
import qs.src.features.dock as DockFeature
import qs.src.features.popouts as Popouts
import qs.src.features.screenshot
import qs.src.features.lockscreen
import qs.src.features.powermenu
import qs.src.features.cheatsheet
import qs.src.core.config
import qs.src.core.services
import Calendar

ShellRoot {
    readonly property var _hws: HyprlandWindowService
    LazyLoader {
        active: AppConfig.moduleEnabled("popouts")
        Popouts.Popouts {
            id: globalPopouts
            Component.onCompleted: PopoutsState.popoutsInstance = globalPopouts
        }
    }

    Variants {
        model: Quickshell.screens
        Scope {
            id: screenScope
            required property ShellScreen modelData

            LazyLoader {
                active: AppConfig.moduleEnabled("bar")
                Bar.StatusBar {
                    id: statusBar
                    screen: screenScope.modelData
                }
            }

            // Dock (per screen)
            LazyLoader {
                active: AppConfig.moduleEnabled("dock")
                DockFeature.Dock {
                    screen: screenScope.modelData
                }
            }

            // Wallpaper (per screen)
            LazyLoader {
                active: AppConfig.moduleEnabled("wallpaper")
                PanelWindow {
                    id: wallpaperPanel
                    screen: screenScope.modelData

                    anchors {
                        left: true
                        top: true
                        right: true
                        bottom: true
                    }
                    exclusionMode: ExclusionMode.Ignore
                    WlrLayershell.namespace: "shell:wallpaper"
                    WlrLayershell.layer: WlrLayershell.Background

                    Wallpaper {
                        anchors.fill: parent
                        screen: wallpaperPanel.screen
                    }
                }
            }
        }
    }

    // Dashboard
    LazyLoader {
        active: AppConfig.moduleEnabled("dashboard") && GlobalStates.dashboardOpen
        Dashboard {}
    }

    // Volume OSD
    LazyLoader {
        active: AppConfig.moduleEnabled("osd")
        VolumeOSD {}
    }

    // Brightness OSD
    LazyLoader {
        active: AppConfig.moduleEnabled("osd")
        BrightnessOSD {}
    }

    // Toast notifications
    LazyLoader {
        active: AppConfig.moduleEnabled("toasts")
        ToastOverlay {}
    }

    // Calendar plugin: bootstrap reminders config and surface errors
    Binding {
        target: CalendarBackend
        property: "remindersEnabled"
        value: AppConfig.calendarRemindersEnabled
    }
    Binding {
        target: CalendarBackend
        property: "reminderMinutes"
        value: AppConfig.calendarReminderMinutes
    }
    Binding {
        target: CalendarBackend
        property: "reminderLookaheadDays"
        value: AppConfig.calendarReminderLookaheadDays
    }
    Connections {
        target: CalendarBackend
        function onErrorOccurred(message) {
            ToastService.error(message)
        }
    }

    // Launcher
    LazyLoader {
        active: AppConfig.moduleEnabled("launcher") && GlobalStates.launcherOpen
        Launcher {}
    }

    // Notification popups
    LazyLoader {
        active: AppConfig.moduleEnabled("notifications")
        NotificationPopupManager {}
    }

    // Notification center
    LazyLoader {
        active: AppConfig.moduleEnabled("notifications") && GlobalStates.notificationCenterOpen
        NotificationCenter {}
    }

    // Screenshot region selection overlay
    LazyLoader {
        active: AppConfig.moduleEnabled("screenshot") && ScreenshotService.screenshotOverlayActive
        ScreenshotOverlay {}
    }

    // Lockscreen (WlSessionLock creates surfaces for each screen internally)
    LazyLoader {
        active: AppConfig.moduleEnabled("lockscreen") && GlobalStates.lockscreenActive
        Lockscreen {}
    }

    // Power menu
    LazyLoader {
        active: AppConfig.moduleEnabled("powerMenu") && GlobalStates.powerMenuOpen
        PowerMenu {}
    }

    // Cheatsheet overlay
    LazyLoader {
        active: AppConfig.moduleEnabled("cheatsheet") && GlobalStates.cheatsheetOpen
        Cheatsheet {}
    }
}