works on NixOS + hyprland with an AMD GPU

[samvanmaele]

works on NixOS + Hyprland on a 5950x and RX 7900 XTX (native OpenXR runtime + xrizer, VRChat via Proton)

Rift CV1 with two sensors. I used the native OpenXR runtime (not the SteamVR driver) with xrizer, so VRChat runs through Proton.
This is the first time i have had working finger tracking in linux so this is a major upgrade over my previous drivers.

after switching from openHMD my headset's HID interfaces had no kernel driver bound, I had to manually rebind it to libusb.

i made a small .nix file too that builds it.

{ pkgs, ... }:
let
 monado-riftlinux = pkgs.monado.overrideAttrs (old: {
   src = pkgs.fetchFromGitHub {
     owner = "AIIX";
     repo = "RiftLinux";
     rev = "cd113cfc3e2b820078fc75f13116007ed81103e7";
     hash = "sha256-om4vKuPlw914BlidegyN/IfdEN6QD3n2SKvGNxW0YZg=";
   };
   patches = [ ];
   buildInputs = old.buildInputs ++ [ pkgs.ceres-solver pkgs.libjpeg_turbo ];
   cmakeFlags = pkgs.lib.remove "-DXRT_HAVE_STEAM:BOOL=TRUE" old.cmakeFlags;
 });

in
{
 systemd.user.services.wayvr = {
   description = "WayVR overlay for Monado";
   wantedBy = [ "monado.service" ];
   bindsTo = [ "monado.service" ];
   after = [ "monado.service" ];
   serviceConfig = {
     ExecStart = "${pkgs.wayvr}/bin/wayvr --openxr";
     Restart = "on-failure";
   };
 };

 services.udev.extraRules = ''
   KERNEL=="hidraw*", ATTRS{idVendor}=="2833", MODE="0660", GROUP="users"
   SUBSYSTEM=="usb", ATTR{idVendor}=="2833", MODE="0660", GROUP="users"
 '';

  services.monado = {
    enable = true;
    defaultRuntime = true;
    package = monado-riftlinux;
  };

  home-manager.users.samvm.xdg.configFile."openvr/openvrpaths.vrpath" = {
    force = true;
    text = builtins.toJSON {
      version = 1;
      jsonid = "vrpathreg";
      external_drivers = null;
      config = [ "/home/samvm/.local/share/Steam/config" ];
      log = [ "/home/samvm/.local/share/Steam/logs" ];
      runtime = [ "${pkgs.xrizer}/lib/xrizer" ];
    };
  };

  home-manager.users.samvm.xdg.configFile."openxr/1/active_runtime.json" = {
    force = true;
    source = "${monado-riftlinux}/share/openxr/1/openxr_monado.json";
  };
}